我在vi中打开了一个Ruby代码文件，其中有行注释为#：
class Search < ActiveRecord::Migration
def self.up
# create_table :searches do |t|
# t.integer :user_id
# t.string :name
# t.string :all_of
# t.string :any_of
# t.string :none_of
# t.string :exact_phrase
#
# t.timestamps
# end
end
def self.down
# drop_table :searches
end
end
假设我想取消注释第一个定义中的所有行。。。端部。在Vim中有什么有效的方法可以做到这一点？
总的来说，我正在寻找一种简单、流畅的方式来注释和取消注释行。这里我处理的是Ruby代码，但可能是JavaScript（//）或Haml（-#）。
当前回答
首先，我要感谢@mike的回答，因为我使用的是它的修改版本。我想发布我的版本，以防有人感兴趣。我的主要功能区别在于，它将始终在射程的每一行上执行相同的动作。如果所选范围包含任何未注释的行，则每一行都会添加注释引线。这样，如果在未注释的代码块中有人类可读的注释，则它们不会变为未注释。然后，当您取消注释块时，人类可读的文本将保持注释状态，因为它有两个注释引线。完成后，它还会恢复光标位置。
ToggleComment函数：
function! ToggleComment() range
"Ensure we know the comment leader.
if !exists('b:comment_leader')
echo "Unknown comment leader."
return
endif
"Save the initial cursor position, to restore later.
let l:inipos = getpos('.')
"Make a list of all of the line numbers in the range which are already commented.
let l:commented_lines = []
for i in range(a:firstline, a:lastline)
if getline(i) =~ '^\s*' . b:comment_leader
let l:commented_lines = add(l:commented_lines, i)
endif
endfor
"If every line in the range is commented, set the action to uncomment.
" Otherwise, set it to comment.
let l:i1 = index(l:commented_lines, a:firstline)
let l:i2 = index(l:commented_lines, a:lastline)
if l:i1 >= 0 && l:i2 >= 0 && (l:i2 - l:i1) == (a:lastline - a:firstline)
let l:action = "uncomment"
else
let l:action = "comment"
endif
"Loop through the range, commenting or uncommenting based on l:action.
for i in range(a:firstline, a:lastline)
"Move to line i.
exec "exe " . i
"Perform the action.
if l:action == "comment"
exec 'normal! 0i' . b:comment_leader
else
execute 'silent s,' . b:comment_leader . ',,'
endif
endfor
"Restore the initial position.
call setpos('.', l:inipos)
endfunction
键映射（注意，我将注释键更改为“k”）：
noremap <Leader>k :call ToggleComment()<CR>
最后，我将autocmds放在下面的“if”语句和augroup中，但它们保持不变。它们大多只是供参考。
if has("autocmd")
augroup autocmds
autocmd!
autocmd FileType c,cpp,java let b:comment_leader = '//'
autocmd FileType arduino let b:comment_leader = '//'
autocmd FileType sh,ruby,python let b:comment_leader = '#'
autocmd FileType zsh let b:comment_leader = '#'
autocmd FileType conf,fstab let b:comment_leader = '#'
autocmd FileType matlab,tex let b:comment_leader = '%'
autocmd FileType vim let b:comment_leader = '"'
augroup END
endif
编辑：我从原始答案更新了ToggleComment函数。最重要的是，我修改了正则表达式。在许多情况下，如果字符串中有另一个注释引线实例，它将无法正常工作。我相信它可能必须在前面或后面加一个空格，但我记不起来了。不管怎样，下面是Python的错误示例。
print("Hello, World!") # Says hello to the world.
我已经解决了这个问题，并稍微简化了正则表达式。一个副作用是它不再在评论标题后面添加空格，但这并不困扰我。我在一些变量中添加了一个局部声明，我在最初的答案中忘记了这些变量。
其他回答
如果您已经知道行号，那么n，ms/#//将起作用。
注释行的一种方法是使用视觉块选择
将光标放在需要注释的行的第0个位置，然后按ctrl+v键进入视觉块。现在使用j（向下）或k（向上）导航到需要注释的行。然后使用c进行切割和插入测试。现在键入“#”以注释，然后键入esc以反映您在选定行上的插入
使用命令模式
选择带有V的行，然后使用j（downwards）k（向上）选择所有需要注释的行，并点击：进入命令模式，看起来像“：<，>”，然后在所选行的开头插入“#”
:'<,'>s/^/#
我使用EnhancedCommentify。它评论了我所需要的一切（编程语言、脚本、配置文件）。我将其用于视觉模式绑定。只需选择要评论的文本，然后按co/cc/cd。
vmap co :call EnhancedCommentify('','guess')<CR>
vmap cc :call EnhancedCommentify('','comment')<CR>
vmap cd :call EnhancedCommentify('','decomment')<CR>
我将Phil和jqno的答案结合起来，并用空格进行了不加修饰的评论：
autocmd FileType c,cpp,java,scala let b:comment_leader = '//'
autocmd FileType sh,ruby,python let b:comment_leader = '#'
autocmd FileType conf,fstab let b:comment_leader = '#'
autocmd FileType tex let b:comment_leader = '%'
autocmd FileType mail let b:comment_leader = '>'
autocmd FileType vim let b:comment_leader = '"'
function! CommentToggle()
execute ':silent! s/\([^ ]\)/' . escape(b:comment_leader,'\/') . ' \1/'
execute ':silent! s/^\( *\)' . escape(b:comment_leader,'\/') . ' \?' . escape(b:comment_leader,'\/') . ' \?/\1/'
endfunction
map <F7> :call CommentToggle()<CR>
工作原理：
假设我们使用#comments。
第一个命令s/\（[^]\）/#\1/搜索第一个非空格字符[^]，并将其替换为#+本身。自身替换由搜索模式中的\（..\）和替换模式中的\1完成。
第二个命令s/^\（*\）#\？#\/\1/搜索以双引号^\（*\）#\？#\？开头的行？（在注释之间接受0或1个空格），并简单地用非注释部分\（*\）替换这些空格（表示前面空格的数量相同）。
有关vim模式的更多详细信息，请查看。
我使用vim 7.4，这对我有用。假设我们正在注释/取消注释3行。
要注释：
如果行的开头没有制表符/空格：ctrl+V然后jjj然后shift+I（capital I）然后//然后esc esc如果该行的开头有制表符/空格，您仍然可以执行上述操作或替换为c：ctrl+V然后jjj然后c然后//然后esc esc取消注释：
如果行的开头没有制表符/空格：ctrl+V，然后jjj，然后ll（下限L），然后c
如果行的开头有制表符/空格，则将一个空格加上escctrl+V，然后jjj，然后ll（下限L），然后c，然后空格，然后esc
