正如其他人所说，您可以使用

:set list

这将与

:set listchars=...

显示不可见字符。现在，没有一个显式选项可以用来显示空白，但在listchars中，您可以设置一个字符来显示除空白以外的所有内容。例如，我的看起来像这样

:set listchars=eol:$,tab:>-,trail:~,extends:>,precedes:<

所以，现在，在你使用

:set list

所有没有明确显示为其他内容的内容实际上都是一个普通的空白。

像往常一样，要了解listchars的工作原理，请使用帮助。它提供了关于可以显示哪些字符（例如尾随空格）以及如何显示的详细信息：

:help listchars

给它添加一个切换可能会很有帮助，这样您可以在编辑过程中轻松看到更改（来源：VIM:set list！作为.virc中的切换）：

noremap <F5> :set list!<CR>
inoremap <F5> <C-o>:set list!<CR>
cnoremap <F5> <C-c>:set list!<CR>

如果设置：

:highlight Search cterm=underline gui=underline ctermbg=none guibg=none ctermfg=none guifg=none

然后搜索空格，每个空格字符将显示为下划线字符。

您可以在切换空格“下划线”的便捷函数中使用此命令。

set hls
let g:HLSpace = 1
let g:HLColorScheme = g:colors_name
function ToggleSpaceUnderscoring()
    if g:HLSpace
        highlight Search cterm=underline gui=underline ctermbg=none guibg=none ctermfg=none guifg=none
        let @/ = " "
    else
        highlight clear
        silent colorscheme "".g:HLColorScheme
        let @/ = ""
    endif
    let g:HLSpace = !g:HLSpace
endfunction

将功能映射到快捷键，快捷键包括：

nmap <silent> <F3> <Esc>:call ToggleSpaceUnderscoring()<CR>

注意：设置配色方案后，在vimrc中定义函数。

下面的代码基于Christian Brabandt的答案，似乎可以按照OP的要求执行：

function! Whitespace()
    if !exists('b:ws')
        highlight Conceal ctermbg=NONE ctermfg=240 cterm=NONE guibg=NONE guifg=#585858 gui=NONE
        highlight link Whitespace Conceal
        let b:ws = 1
    endif

    syntax clear Whitespace
    syntax match Whitespace / / containedin=ALL conceal cchar=·
    setlocal conceallevel=2 concealcursor=c
endfunction

augroup Whitespace
    autocmd!
    autocmd BufEnter,WinEnter * call Whitespace()
augroup END

将这些行添加到~/.vimrc并开始新的Vim会话，以查看仍然不完美的魔术发生。

随意编辑默认颜色和隐藏字符。

注意：几种语言中*FuncBody语法组中的某些内容会阻止显示中间点。我还不知道如何使该解决方案更可靠。

将这些黑客作为注释保存在.vimrc中，因此在shell中，只需：

echo '
  " how-to see the non-visible while spaces
  " :set listchars=eol:¬,tab:>·,trail:~,extends:>,precedes:<,space:␣
  " set listchars=eol:$,tab:>-,trail:~,extends:>,precedes:<
  " :set list
  " but hei how-to unset the visible tabs ?!
  " :set nolist
  ' >> ~/.vimrc

我没有从现有的答案中找到我想要的。下面的代码将突出显示所有的尾部空格亮红色

highlight ExtraWhitespace ctermbg=red guibg=red
match ExtraWhitespace /\s\+$/
autocmd BufWinEnter * match ExtraWhitespace /\s\+$/
autocmd InsertEnter * match ExtraWhitespace /\s\+\%#\@<!$/
autocmd InsertLeave * match ExtraWhitespace /\s\+$/
autocmd BufWinLeave * call clearmatches()

要突出显示空间，只需搜索：

/<空间>

笔记：＜space＞表示只需键入空格字符。使用：set hlsearch启用搜索结果的突出显示

突出显示空格和制表符：/[<space><tab>]

删除高光的快速方法是搜索其他任何内容：/美国国防部

（只需键入任意随机字符的短列表）