如何在Windows命令行中以合适的格式获取当前日期/时间，以便在文件/文件夹名称中使用?

更新:现在是2016年，我将使用PowerShell，除非有一个真正令人信服的向后兼容的原因，特别是因为使用日期的区域设置问题。参见@npocmaka的https://stackoverflow.com/a/19799236/8479

什么是Windows命令行语句(s)，我可以使用以我可以放入文件名的格式获取当前日期时间?

我想要一个.bat文件，它将一个目录压缩成一个归档文件，其中当前日期和时间作为名称的一部分，例如Code_2008-10-14_2257.zip。有什么简单的方法可以做到这一点，独立于机器的区域设置吗?

我真的不介意日期格式，理想情况下它是yyyy-mm-dd，但任何简单的都可以。

到目前为止，我已经得到了这个，在我的机器上给我Tue_10_14_2008_230050_91:

rem Get the datetime in a format that can go in a filename.
set _my_datetime=%date%_%time%
set _my_datetime=%_my_datetime: =_%
set _my_datetime=%_my_datetime::=%
set _my_datetime=%_my_datetime:/=_%
set _my_datetime=%_my_datetime:.=_%

rem Now use the timestamp by in a new ZIP file name.
"d:\Program Files\7-Zip\7z.exe" a -r Code_%_my_datetime%.zip Code

我可以接受这个，但它似乎有点笨重。理想情况下，它应该更简短，并具有前面提到的格式。

我用的是Windows Server 2003和Windows XP Professional。我不想安装额外的实用程序来实现这一点(尽管我知道有一些工具可以很好地格式化日期)。

当前回答

这段代码的前四行将为您提供可靠的YY DD MM YYYY HH Min Sec变量，适用于Windows XP Professional和更高版本。

@echo off
for /f "tokens=2 delims==" %%a in ('wmic OS Get localdatetime /value') do set "dt=%%a"
set "YY=%dt:~2,2%" & set "YYYY=%dt:~0,4%" & set "MM=%dt:~4,2%" & set "DD=%dt:~6,2%"
set "HH=%dt:~8,2%" & set "Min=%dt:~10,2%" & set "Sec=%dt:~12,2%"

set "datestamp=%YYYY%%MM%%DD%" & set "timestamp=%HH%%Min%%Sec%" & set "fullstamp=%YYYY%-%MM%-%DD%_%HH%%Min%-%Sec%"
echo datestamp: "%datestamp%"
echo timestamp: "%timestamp%"
echo fullstamp: "%fullstamp%"
pause

2014-09-07 19:47:40

其他回答

就用这句话:

PowerShell -Command "get-date"

2014-11-19 08:51:50

我也遇到过类似的问题。我每天都会从FTP服务器上自动下载一个加密文件。我想使用gpg解密文件，将文件重命名为当前日期(YYYYMMDD格式)，并将解密文件放入正确部门的文件夹中。

我根据日期查看了几个重命名文件的建议，直到我偶然发现了这个简单的解决方案。

for /f "tokens=1-5 delims=/ " %%d in ("%date%") do rename "decrypted.txt" %%g-%%e-%%f.txt

它工作得很好(例如，文件名显示为“2011-06-14.txt”)。

(源)

2011-06-14 19:02:38

在Windows 7中，这段代码适用于我:

SET DATE=%date%
SET YEAR=%DATE:~0,4%
SET MONTH=%DATE:~5,2%
SET DAY=%DATE:~8,2%
ECHO %YEAR%
ECHO %MONTH%
ECHO %DAY%

SET DATE_FRM=%YEAR%-%MONTH%-%DAY% 
ECHO %DATE_FRM%

2016-08-16 10:44:40

给定一个已知位置，供函数形式参考。ECHOTIMESTAMP调用显示了如何将时间戳转换为变量(本例中为DTS)。

@ECHO off

CALL :ECHOTIMESTAMP
GOTO END

:TIMESTAMP
SETLOCAL  EnableDelayedExpansion
    SET DATESTAMP=!DATE:~10,4!-!DATE:~4,2!-!DATE:~7,2!
    SET TIMESTAMP=!TIME:~0,2!-!TIME:~3,2!-!TIME:~6,2!
    SET DTS=!DATESTAMP: =0!-!TIMESTAMP: =0!
ENDLOCAL & SET "%~1=%DTS%"
GOTO :EOF

:ECHOTIMESTAMP
SETLOCAL
    CALL :TIMESTAMP DTS
    ECHO %DTS%
ENDLOCAL
GOTO :EOF

:END

EXIT /b 0

并保存到文件，timestamp.bat，下面是输出:

2016-08-11 20:07:16

一个基于wmic的函数:

:Now  -- Gets the current date and time into separate variables
::    %~1: [out] Year
::    %~2: [out] Month
::    %~3: [out] Day
::    %~4: [out] Hour
::    %~5: [out] Minute
::    %~6: [out] Second
  setlocal
  for /f %%t in ('wmic os get LocalDateTime ^| findstr /b [0-9]') do set T=%%t
  endlocal & (
    if "%~1" neq "" set %~1=%T:~0,4%
    if "%~2" neq "" set %~2=%T:~4,2%
    if "%~3" neq "" set %~3=%T:~6,2%
    if "%~4" neq "" set %~4=%T:~8,2%
    if "%~5" neq "" set %~5=%T:~10,2%
    if "%~6" neq "" set %~6=%T:~12,2%
  )
goto:eof

优点:独立于地区。缺点:只有系统管理员才能运行wmic.exe。

用法:

call:Now Y M D H N S
echo %Y%-%M%-%D% %H%:%N%:%S%

它像这样回显一个字符串:

2014-01-22 12:51:53

注意，函数形参是外形参——也就是说，您必须提供变量名而不是值。

所有参数都是可选的，因此调用:Now Y M是一个有效的调用，如果您只想获得年和月。

2014-01-22 11:59:17

如何在Windows命令行中以合适的格式获取当前日期/时间，以便在文件/文件夹名称中使用?

推荐文章

最新文章

标签