我注意到o/p并没有要求一个与区域无关的解决方案。不过，我的解决方案是针对英国的。

这是在批处理文件中使用的最简单的解决方案，一行解决方案:

FOR /F "tokens=1-3 delims=/" %%A IN ("%date%") DO (SET today=%%C-%%B-%%A)
echo %today%

可以通过改变输出语句中变量%%A %%B和%%C的顺序来改变该解决方案，以提供所需的任何日期格式(例如YY-MM-DD或DD-MM-YY)。

我发布这个答案的目的——我唯一的目的——是为了证明这可以在命令行上完成，通过使用一行代码来实现。

而且，像其他人那样发布运行35行代码的答案是多余的，因为o/p在问题中特别要求命令行解决方案。因此，o/p专门寻求单线解决方案。

这是我使用的:

::Date Variables - replace characters that are not legal as part of filesystem file names (to produce name like "backup_04.15.08.7z")
SET DT=%date%
SET DT=%DT:/=.%
SET DT=%DT:-=.%

如果你想进一步的想法自动备份到7-Zip档案，我有一个免费/开放的项目，你可以使用或审查的想法:http://wittman.org/ziparcy/

这并不是真的更简短，但可能是一种更灵活的方式(来源):

FOR /F "TOKENS=1* DELIMS= " %%A IN ('DATE/T') DO SET CDATE=%%B
FOR /F "TOKENS=1,2 eol=/ DELIMS=/ " %%A IN ('DATE/T') DO SET mm=%%B
FOR /F "TOKENS=1,2 DELIMS=/ eol=/" %%A IN ('echo %CDATE%') DO SET dd=%%B
FOR /F "TOKENS=2,3 DELIMS=/ " %%A IN ('echo %CDATE%') DO SET yyyy=%%B
SET date=%mm%%dd%%yyyy%

一个基于wmic的函数:

:Now  -- Gets the current date and time into separate variables
::    %~1: [out] Year
::    %~2: [out] Month
::    %~3: [out] Day
::    %~4: [out] Hour
::    %~5: [out] Minute
::    %~6: [out] Second
  setlocal
  for /f %%t in ('wmic os get LocalDateTime ^| findstr /b [0-9]') do set T=%%t
  endlocal & (
    if "%~1" neq "" set %~1=%T:~0,4%
    if "%~2" neq "" set %~2=%T:~4,2%
    if "%~3" neq "" set %~3=%T:~6,2%
    if "%~4" neq "" set %~4=%T:~8,2%
    if "%~5" neq "" set %~5=%T:~10,2%
    if "%~6" neq "" set %~6=%T:~12,2%
  )
goto:eof

优点:独立于地区。缺点:只有系统管理员才能运行wmic.exe。

用法:

call:Now Y M D H N S
echo %Y%-%M%-%D% %H%:%N%:%S%

它像这样回显一个字符串:

2014-01-22 12:51:53

注意，函数形参是外形参——也就是说，您必须提供变量名而不是值。

所有参数都是可选的，因此调用:Now Y M是一个有效的调用，如果您只想获得年和月。

另一种方法(credit):

@For /F "tokens=2,3,4 delims=/ " %%A in ('Date /t') do @( 
    Set Month=%%A
    Set Day=%%B
    Set Year=%%C
)

@echo DAY = %Day%
@echo Month = %Month%
@echo Year = %Year%

请注意，我在这里的答案仍然依赖于日期和月份的顺序，由区域设置决定-不知道如何解决这个问题。

在Windows 7中，这段代码适用于我:

SET DATE=%date%
SET YEAR=%DATE:~0,4%
SET MONTH=%DATE:~5,2%
SET DAY=%DATE:~8,2%
ECHO %YEAR%
ECHO %MONTH%
ECHO %DAY%

SET DATE_FRM=%YEAR%-%MONTH%-%DAY% 
ECHO %DATE_FRM%