我编写了一个powerbasic程序wait.exe，在批处理文件中向它传递一个毫秒参数

wait 3000
system('c:/windows/system32/SnippingTool.exe')

EXE的代码：

FUNCTION PBMAIN()
  c$ = Command$
  s! = Val(c$)*1000
  Sleep s!         
END FUNCTION

在较新的Windows OS版本上，可以使用以下命令

sleep /w2000

在DOS脚本（.cmd或.bat）中等待2s（2000毫秒-替换所需的毫秒）。请注意包含/w参数-如果没有它，整个计算机都将进入睡眠状态！如果需要，可以使用-m代替/m，也可以在w和数字之间使用冒号（：）。

如果你有选择或ping，这是可行的。

@echo off
echo.
if "%1"=="" goto askq
if "%1"=="/?" goto help
if /i "%1"=="/h" goto help
if %1 GTR 0 if %1 LEQ 9999 if /i "%2"=="/q" set ans1=%1& goto quiet
if %1 GTR 0 if %1 LEQ 9999 set ans1=%1& goto breakout
if %1 LEQ 0 echo %1 is not a valid number & goto help
if not "%1"=="" echo.&echo "%1" is a bad parameter & goto help
goto end

:help
echo SLEEP runs interactively (by itself) or with parameters (sleep # /q )
echo where # is in seconds, ranges from 1 - 9999
echo Use optional parameter /q to suppress standard output 
echo or type /h or /? for this help file
echo.
goto end

:askq
set /p ans1=How many seconds to sleep? ^<1-9999^> 
echo.
if "%ans1%"=="" goto askq
if %ans1% GTR 0 if %ans1% LEQ 9999 goto breakout
goto askq

:quiet
choice /n /t %ans1% /d n > nul
if errorlevel 1 ping 1.1.1.1 -n 1 -w %ans1%000 > nul
goto end

:breakout
choice /n /t %ans1% /d n > nul
if errorlevel 1 ping 1.1.1.1 -n 1 -w %ans1%000 > nul
echo Slept %ans1% second^(s^)
echo.

:end

只需将其命名为sleep.cmd或sleep.bat并运行它

创建名为sleep.cmd的cmd文件：

REM Usage: SLEEP Time_in_MiliSECONDS
@ECHO off
ping 1.0.0.0 -n 1 -w %1 > nul

将sleep.cmd复制到c:\windows\system32

用法：

sleep 500

睡眠0.5秒。以毫秒为单位的参数一旦复制到System32，就可以在任何地方使用。

编辑：你还应该注意，如果机器没有连接到网络（比如你在地铁中使用的便携式设备），ping技巧就不再有效了。

这可以通过批处理文件中的两行简单代码来完成：在%temp%文件夹中写一个临时.vbs文件，并调用它：

echo WScript.Sleep(5000) >"%temp%\sleep.vbs"
cscript "%temp%\sleep.vbs"

还有两种方法可以处理XP及以上版本的所有内容：

具有w32tm：

w32tm /stripchart /computer:localhost /period:5 /dataonly /samples:2  1>nul 

类型为perf:

typeperf "\System\Processor Queue Length" -si 5 -sc 1 >nul

使用mshta（不需要设置网络）：

start "" /w /b /min mshta "javascript:setTimeout(function(){close();},5000);"