注意:mksession不会将所做的更改保存到任何文件中。我犯了这个错误，在保存会话后关闭vim，假设我将从那里开始。但是当我再次打开会话时，我对文件所做的更改已经消失了。

下面是唯一一个对我有用的对话。我从这里开始，你也可以从这里得到一个更完整/复杂的版本。

set viewoptions+=cursor,folds,slash,unix
set viewoptions-=options

augroup vimrc
    autocmd BufWritePost *
    \   if expand('%') != '' && &buftype !~ 'nofile'
    \|      mkview
    \|  endif
    autocmd BufRead *
    \   if expand('%') != '' && &buftype !~ 'nofile'
    \|      silent loadview
    \|  endif
augroup END

因为这是谷歌上对我(可能还有其他人)的第一次打击，关于如何在Vim中使用会话，我决定在@mathielo的回答中添加一点关于如何使此自动。

我喜欢他的代码，但“仅当不带参数时”的解决方案似乎有点不足。这是我修改过的版本:

function! MakeSession(overwrite)
  let b:sessiondir = $HOME . "/.vim/sessions" . getcwd()
  if (filewritable(b:sessiondir) != 2)
    exe 'silent !mkdir -p ' b:sessiondir
    redraw!
  endif
  let b:filename = b:sessiondir . '/session.vim'
  if a:overwrite == 0 && !empty(glob(b:filename))
    return
  endif
  exe "mksession! " . b:filename
endfunction

function! LoadSession()
  let b:sessiondir = $HOME . "/.vim/sessions" . getcwd()
  let b:sessionfile = b:sessiondir . "/session.vim"
  if (filereadable(b:sessionfile))
    exe 'source ' b:sessionfile
  else
    echo "No session loaded."
  endif
endfunction

" Adding automatons for when entering or leaving Vim
if(argc() == 0)
  au VimEnter * nested :call LoadSession()
  au VimLeave * :call MakeSession(1)
else
  au VimLeave * :call MakeSession(0)
endif

这里值得注意的变化是可选的覆盖。如果你打开没有选项的Vim，它将打开任何现有的会话，并覆盖你离开时所做的更改。如果Vim是带选项打开的，它只会在不存在会话的情况下创建一个新的会话，这意味着您可以在一个有会话的目录中打开单个文件而不会覆盖它。然后可以打开不带选项的Vim来运行会话。如果不存在会话，则创建一个新的会话。

如果你使用NERDTree作为文件资源管理器/dash，我推荐xolox/vim-session插件，而不是内置的:mksession命令。由于某种原因，:mksession无法恢复NERDTree缓冲区。你的观点可能不同，但我想分享一下我的经验。

注意:mksession不会将所做的更改保存到任何文件中。我犯了这个错误，在保存会话后关闭vim，假设我将从那里开始。但是当我再次打开会话时，我对文件所做的更改已经消失了。

如果你想在不使用任何插件的情况下自动化这个过程，你可以使用Go away，然后从Vim Tips Wiki返回。

每次退出Vim时，它都会将当前会话保存在~/下。vim/会话，并在打开vim后再次加载它。它也基于您当前的路径，因此如果您从不同的目录打开Vim，您将有不同的会话，这在处理不同的项目时非常有用。

只需编辑~/。Vimrc文件，并添加以下内容:

function! MakeSession()
  let b:sessiondir = $HOME . "/.vim/sessions" . getcwd()
  if (filewritable(b:sessiondir) != 2)
    exe 'silent !mkdir -p ' b:sessiondir
    redraw!
  endif
  let b:filename = b:sessiondir . '/session.vim'
  exe "mksession! " . b:filename
endfunction

function! LoadSession()
  let b:sessiondir = $HOME . "/.vim/sessions" . getcwd()
  let b:sessionfile = b:sessiondir . "/session.vim"
  if (filereadable(b:sessionfile))
    exe 'source ' b:sessionfile
  else
    echo "No session loaded."
  endif
endfunction

" Adding automatons for when entering or leaving Vim
au VimEnter * nested :call LoadSession()
au VimLeave * :call MakeSession()

即使对于初学者来说，这个脚本也很容易理解和定制。

请注意，此脚本仅适用于Unix系统(MacOS/Linux)，需要在Windows上进行调整。

更新:添加0xc0de的建议，如果你想让Vim只在没有提供参数的情况下加载会话，你可以替换这些VimEnter行:

if(argc() == 0)
  au VimEnter * nested :call LoadSession()
endif