如果你计划只有一个阶段的项目，那就这样做

:mks

这将创建一个Session。Vim文件在当前目录，然后打开会话(从同一目录):

vim -S

如果您更改会话并想要保存它:

:mks!

这将保存会话，而不是文件本身!

如果你计划有多个会话，我更喜欢将它们保存在项目目录中的隐藏文件中:

:mks .session-name.vim

打开它(从同一目录):

vim -S .session-name.vim

保存会话:

:mks! .session-name.vim

由于会话保存在隐藏文件中，要查看它们不要忘记-a

ls -a

有一个叫vim-session的插件。它非常强大。安装方法:

cd ~/.vim/bundle
git clone https://github.com/xolox/vim-session.git

我在我的.vimrc文件中映射了它的功能，就像这样:

nnoremap <leader>so :OpenSession 
nnoremap <leader>ss :SaveSession 
nnoremap <leader>sd :DeleteSession<CR>
nnoremap <leader>sc :CloseSession<CR>

现在在正常模式下输入<leader>ss，你会看到这样的命令

:SaveSession 

现在添加会话的名称

 :SaveSession namesession

就这些。

当你关闭Vim并重新打开它时，就这么做

 :OpenSession

你会看到你的会议开始了。

在你的.vimrc文件中还有很多其他的配置需要添加，参见文档中的例子:

let g:session_directory = "~/.vim/tmp/session"  // the directory must be created before the sessions will be saved there
let g:session_autoload = "no"                   // automatic reload sessions
let g:session_autosave = "no"                   // autosave
let g:session_command_aliases = 1

YouTube上有一个很好的教程。

如果你想在不使用任何插件的情况下自动化这个过程，你可以使用Go away，然后从Vim Tips Wiki返回。

每次退出Vim时，它都会将当前会话保存在~/下。vim/会话，并在打开vim后再次加载它。它也基于您当前的路径，因此如果您从不同的目录打开Vim，您将有不同的会话，这在处理不同的项目时非常有用。

只需编辑~/。Vimrc文件，并添加以下内容:

function! MakeSession()
  let b:sessiondir = $HOME . "/.vim/sessions" . getcwd()
  if (filewritable(b:sessiondir) != 2)
    exe 'silent !mkdir -p ' b:sessiondir
    redraw!
  endif
  let b:filename = b:sessiondir . '/session.vim'
  exe "mksession! " . b:filename
endfunction

function! LoadSession()
  let b:sessiondir = $HOME . "/.vim/sessions" . getcwd()
  let b:sessionfile = b:sessiondir . "/session.vim"
  if (filereadable(b:sessionfile))
    exe 'source ' b:sessionfile
  else
    echo "No session loaded."
  endif
endfunction

" Adding automatons for when entering or leaving Vim
au VimEnter * nested :call LoadSession()
au VimLeave * :call MakeSession()

即使对于初学者来说，这个脚本也很容易理解和定制。

请注意，此脚本仅适用于Unix系统(MacOS/Linux)，需要在Windows上进行调整。

更新:添加0xc0de的建议，如果你想让Vim只在没有提供参数的情况下加载会话，你可以替换这些VimEnter行:

if(argc() == 0)
  au VimEnter * nested :call LoadSession()
endif

如果你使用NERDTree作为文件资源管理器/dash，我推荐xolox/vim-session插件，而不是内置的:mksession命令。由于某种原因，:mksession无法恢复NERDTree缓冲区。你的观点可能不同，但我想分享一下我的经验。

为了管理多个会话(在每个目录/回购的基础上)，我最近从vim-session插件切换到vim-workspace。它的会话管理相对简单，工作得很好。

因为这是谷歌上对我(可能还有其他人)的第一次打击，关于如何在Vim中使用会话，我决定在@mathielo的回答中添加一点关于如何使此自动。

我喜欢他的代码，但“仅当不带参数时”的解决方案似乎有点不足。这是我修改过的版本:

function! MakeSession(overwrite)
  let b:sessiondir = $HOME . "/.vim/sessions" . getcwd()
  if (filewritable(b:sessiondir) != 2)
    exe 'silent !mkdir -p ' b:sessiondir
    redraw!
  endif
  let b:filename = b:sessiondir . '/session.vim'
  if a:overwrite == 0 && !empty(glob(b:filename))
    return
  endif
  exe "mksession! " . b:filename
endfunction

function! LoadSession()
  let b:sessiondir = $HOME . "/.vim/sessions" . getcwd()
  let b:sessionfile = b:sessiondir . "/session.vim"
  if (filereadable(b:sessionfile))
    exe 'source ' b:sessionfile
  else
    echo "No session loaded."
  endif
endfunction

" Adding automatons for when entering or leaving Vim
if(argc() == 0)
  au VimEnter * nested :call LoadSession()
  au VimLeave * :call MakeSession(1)
else
  au VimLeave * :call MakeSession(0)
endif

这里值得注意的变化是可选的覆盖。如果你打开没有选项的Vim，它将打开任何现有的会话，并覆盖你离开时所做的更改。如果Vim是带选项打开的，它只会在不存在会话的情况下创建一个新的会话，这意味着您可以在一个有会话的目录中打开单个文件而不会覆盖它。然后可以打开不带选项的Vim来运行会话。如果不存在会话，则创建一个新的会话。