只需发布此Windows的单行批处理文件：

C:>type wh.cmd
@for %%f in (%*) do for %%e in (%PATHEXT% .dll .lnk) do for %%b in (%%f%%e) do for %%d in (%PATH%) do if exist %%d\%%b echo %%d\%%b

A测试：

C:>wh ssh
C:\cygwin64\bin\ssh.EXE
C:\Windows\System32\OpenSSH\\ssh.EXE

如果将代码包装在setlocalenableextensions和endlocal中，那就不是一行了。

我在互联网上找到的Unix Win32端口没有一个是令人满意的，因为它们都有一个或多个缺点：

不支持Windows PATHEXT变量。（它定义了在扫描路径之前隐式添加到每个命令的扩展列表，以及顺序。）（我使用了很多tcl脚本，没有公开可用的工具可以找到它们。）不支持cmd.exe代码页，这会使它们错误地显示带有非ascii字符的路径。（我对此非常敏感，我的名字中有一个ç：-）cmd.exe和PowerShell命令行中不支持不同的搜索规则。（没有公开可用的工具可以在PowerShell窗口中找到.ps1脚本，但在cmd窗口中找不到！）

所以我最终写了我自己的，这正确地支持了以上所有内容。

此处可用：http://jf.larvoire.free.fr/progs/which.exe

Windows Server 2003及更高版本（即Windows XP 32位之后的任何版本）提供了where.exe程序，该程序可以执行某些操作，尽管它匹配所有类型的文件，而不仅仅是可执行命令。（它与内置的shell命令（如cd）不匹配。）它甚至会接受通配符，因此nt*可以在%PATH%和当前目录中查找名称以nt开头的所有文件。

尝试在哪里/？寻求帮助。

请注意，Windows PowerShell将where定义为where-Object cmdlet的别名，因此如果需要where.exe，则需要键入全名，而不是省略.exe扩展名。或者，您可以为其设置别名：

Set-Alias which where.exe

更新：建议使用Get命令（别名：gcm），因为它是PS的本机命令，并将获取所有命令类型：别名、cmdlet、可执行文件和函数。例子：

gcm notepad*

我正在使用GOW（Windows上的GNU），这是Cygwin的一个轻量级版本。你可以在这里从GitHub获取它。

GOW（Windows上的GNU）是Cygwin的轻量级替代品。它使用一个方便的Windows安装程序，可安装大约130个编译为本机win32的有用的开源UNIX应用程序二进制文件。它设计得尽可能小，大约10 MB与Cygwin相反，Cygwin可以运行超过100 MB，这取决于选项。-关于描述（Brent R.Matzelle）

GOW中包含的命令列表截图：

虽然较新版本的Windows具有where命令，但您也可以使用环境变量修饰符在Windows XP中执行此操作，如下所示：

c:\> for %i in (cmd.exe) do @echo.   %~$PATH:i
   C:\WINDOWS\system32\cmd.exe

c:\> for %i in (python.exe) do @echo.   %~$PATH:i
   C:\Python25\python.exe

您不需要任何额外的工具，也不限于PATH，因为您可以替换任何您希望使用的环境变量（当然是路径格式）。

而且，如果你想要一个能够处理PATHEXT中所有扩展的系统（就像Windows本身一样），这个系统可以做到：

@echo off
setlocal enableextensions enabledelayedexpansion

:: Needs an argument.

if "x%1"=="x" (
    echo Usage: which ^<progName^>
    goto :end
)

:: First try the unadorned filenmame.

set fullspec=
call :find_it %1

:: Then try all adorned filenames in order.

set mypathext=!pathext!
:loop1
    :: Stop if found or out of extensions.

    if "x!mypathext!"=="x" goto :loop1end

    :: Get the next extension and try it.

    for /f "delims=;" %%j in ("!mypathext!") do set myext=%%j
    call :find_it %1!myext!

:: Remove the extension (not overly efficient but it works).

:loop2
    if not "x!myext!"=="x" (
        set myext=!myext:~1!
        set mypathext=!mypathext:~1!
        goto :loop2
    )
    if not "x!mypathext!"=="x" set mypathext=!mypathext:~1!

    goto :loop1
:loop1end

:end
endlocal
goto :eof

:: Function to find and print a file in the path.

:find_it
    for %%i in (%1) do set fullspec=%%~$PATH:i
    if not "x!fullspec!"=="x" @echo.   !fullspec!
    goto :eof

它实际上返回所有可能性，但您可以很容易地针对特定搜索规则进行调整。

在Windows PowerShell中：

set-alias which where.exe