如何执行SELECT*INTO[temp table]FROM[存储过程]？不是FROM[Table]并且没有定义[temp Table]？
选择BusinessLine中的所有数据到tmpBusLine工作正常。
select *
into tmpBusLine
from BusinessLine
我也在尝试同样的方法，但使用返回数据的存储过程并不完全相同。
select *
into tmpBusLine
from
exec getBusinessLineHistory '16 Mar 2009'
输出消息：
消息156，级别15，状态1，第2行关键字附近的语法不正确“exec”。
我读过几个创建与输出存储过程结构相同的临时表的示例，这很好，但最好不要提供任何列。
当前回答
此存储过程执行以下任务：
CREATE PROCEDURE [dbo].[ExecIntoTable]
(
@tableName NVARCHAR(256),
@storedProcWithParameters NVARCHAR(MAX)
)
AS
BEGIN
DECLARE @driver VARCHAR(10)
DECLARE @connectionString NVARCHAR(600)
DECLARE @sql NVARCHAR(MAX)
DECLARE @rowsetSql NVARCHAR(MAX)
SET @driver = '''SQLNCLI'''
SET @connectionString =
'''server=' +
CAST(SERVERPROPERTY('ServerName') AS NVARCHAR(256)) +
COALESCE('\' + CAST(SERVERPROPERTY('InstanceName') AS NVARCHAR(256)), '') +
';trusted_connection=yes'''
SET @rowsetSql = '''EXEC ' + REPLACE(@storedProcWithParameters, '''', '''''') + ''''
SET @sql = '
SELECT
*
INTO
' + @tableName + '
FROM
OPENROWSET(' + @driver + ',' + @connectionString + ',' + @rowsetSql + ')'
EXEC (@sql)
END
GO
这是一个轻微的修改：将存储过程结果插入到表中，使其实际工作。
如果希望它与临时表一起工作，则需要使用##GLOBAL表，然后将其删除。
其他回答
在四处搜索之后，我找到了一种方法，可以在不使用OPENROWSET或OPENQUERY的情况下，使用存储过程结果定义的通用模式为任何存储过程动态创建临时表，特别是当您不是数据库管理员时。
Sql服务器有一个内置过程sp_describe_first_result_set，它可以为您提供任何过程结果集的模式。我根据这个过程的结果创建了一个模式表，并手动将所有字段设置为NULLABLE。
declare @procname varchar(100) = 'PROCEDURENAME' -- your procedure name
declare @param varchar(max) = '''2019-06-06''' -- your parameters
declare @execstr nvarchar(max) = N'exec ' + @procname
declare @qry nvarchar(max)
-- Schema table to store the result from sp_describe_first_result_set.
create table #d
(is_hidden bit NULL, column_ordinal int NULL, name sysname NULL, is_nullable bit NULL, system_type_id int NULL, system_type_name nvarchar(256) NULL,
max_length smallint NULL, precision tinyint NULL, scale tinyint NULL, collation_name sysname NULL, user_type_id int NULL, user_type_database sysname NULL,
user_type_schema sysname NULL,user_type_name sysname NULL,assembly_qualified_type_name nvarchar(4000),xml_collection_id int NULL,xml_collection_database sysname NULL,
xml_collection_schema sysname NULL,xml_collection_name sysname NULL,is_xml_document bit NULL,is_case_sensitive bit NULL,is_fixed_length_clr_type bit NULL,
source_server sysname NULL,source_database sysname NULL,source_schema sysname NULL,source_table sysname NULL,source_column sysname NULL,is_identity_column bit NULL,
is_part_of_unique_key bit NULL,is_updateable bit NULL,is_computed_column bit NULL,is_sparse_column_set bit NULL,ordinal_in_order_by_list smallint NULL,
order_by_list_length smallint NULL,order_by_is_descending smallint NULL,tds_type_id int NULL,tds_length int NULL,tds_collation_id int NULL,
tds_collation_sort_id tinyint NULL)
-- Get result set definition of your procedure
insert into #d
EXEC sp_describe_first_result_set @exestr, NULL, 0
-- Create a query to generate and populate a global temp table from above results
select
@qry = 'Create table ##t(' +
stuff(
(select ',' + name + ' '+ system_type_name + ' NULL'
from #d d For XML Path, TYPE)
.value(N'.[1]', N'nvarchar(max)')
, 1,1,'')
+ ')
insert into ##t
Exec '+@procname+' ' + @param
Exec sp_executesql @qry
-- Use below global temp table to query the data as you may
select * from ##t
-- **WARNING** Don't forget to drop the global temp table ##t.
--drop table ##t
drop table #d
在Sql Server版本-Microsoft Sql Server 2016（RTM）-13.0.1601.5（版本17134:）上开发和测试
您可以调整正在使用的SQL server版本的模式（如果需要）。
嗯，您确实需要创建一个临时表，但它不需要有正确的模式。。。。我创建了一个存储过程，它修改了现有的临时表，使其具有正确的数据类型和顺序（删除所有现有列，添加新列）所需的列：
GO
create procedure #TempTableForSP(@tableId int, @procedureId int)
as
begin
declare @tableName varchar(max) = (select name
from tempdb.sys.tables
where object_id = @tableId
);
declare @tsql nvarchar(max);
declare @tempId nvarchar(max) = newid();
set @tsql = '
declare @drop nvarchar(max) = (select ''alter table tempdb.dbo.' + @tableName
+ ' drop column '' + quotename(c.name) + '';''+ char(10)
from tempdb.sys.columns c
where c.object_id = ' +
cast(@tableId as varchar(max)) + '
for xml path('''')
)
alter table tempdb.dbo.' + @tableName + ' add ' + QUOTENAME(@tempId) + ' int;
exec sp_executeSQL @drop;
declare @add nvarchar(max) = (
select ''alter table ' + @tableName
+ ' add '' + name
+ '' '' + system_type_name
+ case when d.is_nullable=1 then '' null '' else '''' end
+ char(10)
from sys.dm_exec_describe_first_result_set_for_object('
+ cast(@procedureId as varchar(max)) + ', 0) d
order by column_ordinal
for xml path(''''))
execute sp_executeSQL @add;
alter table ' + @tableName + ' drop column ' + quotename(@tempId) + ' ';
execute sp_executeSQL @tsql;
end
GO
create table #exampleTable (pk int);
declare @tableId int = object_Id('tempdb..#exampleTable')
declare @procedureId int = object_id('examplestoredProcedure')
exec #TempTableForSP @tableId, @procedureId;
insert into #exampleTable
exec examplestoredProcedure
请注意，如果sys.dm_exec_descript_first_result_set_for_object无法确定存储过程的结果（例如，如果它使用临时表），则这将不起作用。
我正在使用以下模式和数据创建一个表。创建存储过程。现在我知道我的过程的结果是什么，所以我正在执行以下查询。创建表[dbo]。[tbl测试树]([Id][int]标识（1,1）不为空，[ParentId][int]NULL，[IsLeft][bit]NULL，[IsRight][bit]NULL，CONSTRAINT[PK_tblTestingTree]主键集群([Id]ASC)（PAD_INDEX=关闭，STATISTICS_NORECOMPUTE=关闭，IGNORE_DUP_KEY=关闭，ALLOW_ROW_LOCKS=打开，ALLOW_PAGE_LOCKS=开启）打开[主])在[主要]去设置IDENTITY_INSERT[dbo]。[tbl测试树]打开插入[dbo]。[tblTestingTree]（[Id]，[ParentId]，[IsLeft]，[IsRight]）值（1，NULL，NULL，空）插入[dbo]。[tblTestingTree]（[Id]，[ParentId]，[IsLeft]，[IsRight]）值（2，1，1，NULL）插入[dbo]。[tblTestingTree]（[Id]，[ParentId]，[IsLeft]，[IsRight]）值（3，1，NULL，1）插入[dbo]。[tblTestingTree]（[Id]，[ParentId]，[IsLeft]，[IsRight]）值（4，2，1，NULL）插入[dbo]。[tblTestingTree]（[Id]，[ParentId]，[IsLeft]，[IsRight]）值（5，2，NULL，1）插入[dbo]。[tblTestingTree]（[Id]，[ParentId]，[IsLeft]，[IsRight]）值（6，3，1，NULL）插入[dbo]。[tblTestingTree]（[Id]，[ParentId]，[IsLeft]，[IsRight]）值（7，3，NULL，1）插入[dbo]。[tblTestingTree]（[Id]，[ParentId]，[IsLeft]，[IsRight]）值（8，4，1，NULL）插入[dbo]。[tblTestingTree]（[Id]，[ParentId]，[IsLeft]，[IsRight]）值（9，4，NULL，1）插入[dbo]。[tblTestingTree]（[Id]，[ParentId]，[IsLeft]，[IsRight]）值（10，5，1，NULL）设置IDENTITY_INSERT[dbo]。[tbl测试树]关闭值（10，5，1，NULL）设置IDENTITY_INSERT[dbo]。[tblTestingTree]打开创建过程GetDate像开始从tblTestingTree中选择Id、ParentId终止创建表tbltemp(id int，父ID int)插入tbltempexec获取日期从tbltemp中选择*；
在SQL Server 2005中，可以使用INSERT INTO。。。EXEC将存储过程的结果插入到表中。从MSDN的INSERT文档中（实际上是针对SQL Server 2000）：
--INSERT...EXECUTE procedure example
INSERT author_sales EXECUTE get_author_sales
存储过程是否只检索数据或修改数据？如果它仅用于检索，则可以将存储过程转换为函数并使用公共表表达式（CTE），而无需声明它，如下所示：
with temp as (
select * from dbo.fnFunctionName(10, 20)
)
select col1, col2 from temp
然而，需要从CTE中检索的内容只能在一个语句中使用。你不能用temp做。。。并尝试在几行SQL之后使用它。对于更复杂的查询，可以在一个语句中包含多个CTE。
例如
with temp1020 as (
select id from dbo.fnFunctionName(10, 20)
),
temp2030 as (
select id from dbo.fnFunctionName(20, 30)
)
select * from temp1020
where id not in (select id from temp2030)
