如何使用sed命令将换行符（“\n”）替换为空格（“”）？
我尝试过：
sed 's#\n# #g' file
sed 's#^$# #g' file
如何修复？
当前回答
sed '1h;1!H;$!d
x;s/\n/ /g' YourFile
这不适用于巨大的文件（缓冲区限制），但如果有足够的内存来保存文件，则非常有效。（更正H->1h；在@hilojack的好话之后1！H）
另一个在读取时更改新行的版本（更多的cpu，更少的内存）
sed ':loop
$! N
s/\n/ /
t loop' YourFile
其他回答
我特别喜欢的解决方案是在保留空间中追加所有文件，并替换文件末尾的所有换行符：
$ (echo foo; echo bar) | sed -n 'H;${x;s/\n//g;p;}'
foobar
然而，有人告诉我，在一些sed实现中，保持空间可能是有限的。
答案是：标签。。。
如何使用sed替换换行符？
…在命令行的freebsd 7.2中不起作用：
( echo foo ; echo bar ) | sed ':a;N;$!ba;s/\n/ /g' sed: 1: ":a;N;$!ba;s/\n/ /g": unused label 'a;N;$!ba;s/\n/ /g' foo bar
但如果您将sed脚本放在文件中或使用-e“构建”sed脚本。。。
> (echo foo; echo bar) | sed -e :a -e N -e '$!ba' -e 's/\n/ /g' foo bar
或
> cat > x.sed << eof
:a
N
$!ba
s/\n/ /g
eof
> (echo foo; echo bar) | sed -f x.sed
foo bar
也许OS X中的sed是类似的。
这可能适用于您（GNU sed）：
sed 'H;$!d;x;:a;s/^((.).*)\2/\1 /;ta;s/.//' file
H命令在模式空间前面加一个换行符，然后将结果附加到保留空间。sed的正常流程是从每一行中删除以下换行符，因此这将在保留空间的开头引入一个换行符，并复制文件的其余部分。一旦文件被拖入保留空间，就用模式空间替换保留空间，然后使用模式匹配将所有原始换行替换为空格。最后，删除引入的换行符。
这样做的优点是，在sed命令中永远不会实际输入换行字符串。
备选方案：
sed 'H;$!d;x;y/\n/ /;s/.//' file
Or:
sed 'H;1h;$!d;x;y/\n/ /' file
另一种GNU sed方法，几乎与Zsolt Botykai的答案相同，但这使用了sed不太常用的y（音译）命令，这节省了一个字节的代码（后面的g）：
sed ':a;N;$!ba;y/\n/ /'
人们可能希望y的运行速度比s快（也许以tr的速度，快20倍），但在GNU sed v4.2.2中，y比s慢4%左右。
更便携的BSD sed版本：
sed -e ':a' -e 'N;$!ba' -e 'y/\n/ /'
这里是没有缓冲区的sed（适用于实时输出）。示例：在HTML中用<br/>break替换\n
echo -e "1\n2\n3" | sed 's/.*$/&<br\/>/'
