在Windows (Windows XP)批处理脚本中，我需要格式化当前日期和时间，以便以后在文件名等中使用。
这类似于堆栈溢出问题如何在批处理文件中添加日期，但也包含时间。
到目前为止，我有这个:
echo %DATE%
echo %TIME%
set datetimef=%date:~-4%_%date:~3,2%_%date:~0,2%__%time:~0,2%_%time:~3,2%_%time:~6,2%
echo %datetimef%
这使:
28/07/2009
8:35:31.01
2009_07_28__ 8_36_01
是否有一种方法可以允许%TIME%中的个位数小时，以便我可以得到以下结果?
2009_07_28__08_36_01
当前回答
::========================================================================
::== CREATE UNIQUE DATETIME STRING IN FORMAT YYYYMMDD-HHMMSS
::======= ================================================================
FOR /f %%a IN ('WMIC OS GET LocalDateTime ^| FIND "."') DO SET DTS=%%a
SET DATETIME=%DTS:~0,8%-%DTS:~8,6%
第一行输出的格式与时区无关: 20150515150941.077000 + 120 这样，您只需按照自己的愿望格式化输出即可。
其他回答
我喜欢@The lorax上面的简短版本， 但对于其他语言设置可能略有不同。
例如，在德语设置中(使用自然日期格式:dd.mm.yyyy)，月份查询必须从4,2更改为3,2:
@ECHO OFF
: Sets the proper date and time stamp with 24h time for log file naming convention i.e.
SET HOUR=%time:~0,2%
SET dtStamp9=%date:~-4%%date:~3,2%%date:~7,2%_0%time:~1,1%%time:~3,2%%time:~6,2%
SET dtStamp24=%date:~-4%%date:~3,2%%date:~7,2%_%time:~0,2%%time:~3,2%%time:~6,2%
if "%HOUR:~0,1%" == " " (SET dtStamp=%dtStamp9%) else (SET dtStamp=%dtStamp24%)
ECHO %dtStamp%
: Outputs= 20160727_081040
: (format: YYYYMMDD_HHmmss; e.g.: the date-output of this post timestamp)
PAUSE
如果你不需要这个格式:
2009_07_28__08_36_01
然后你可以使用以下3行代码，使用%date%和%time%:
set mydate=%date:/=%
set mytime=%time::=%
set mytimestamp=%mydate: =_%_%mytime:.=_%
注意:字符/和:被删除，字符。空格被下划线取代。
示例输出(摄于8/5/15星期三下午12:49，时间为50秒93毫秒):
echo %mytimestamp%
Wed_08052015_124950_93
为了生成一个YYYY-MM-DD hh:mm:ss(24小时)时间戳，我使用:
SET CURRENTTIME=%TIME%
IF "%CURRENTTIME:~0,1%"==" " (SET CURRENTTIME=0%CURRENTTIME:~1%)
FOR /F "tokens=2-4 delims=/ " %%A IN ('DATE /T') DO (SET TIMESTAMP=%%C-%%A-%%B %CURRENTTIME%)
希望这能有所帮助:
set MM=%date:~4,2%
set DD=%date:~7,2%
set YYYY=%date:~10,4%
echo %DD%_%MM%_%YYYY%
这将打印05_06_2021
你可以用这些…
Parameters:
%date:~4,2% -- month
%date:~7,2% -- days
%date:~10,4% -- years
%time:~1,1% -- hours
%time:~3,2% -- minutes
%time:~6,2% -- seconds
%time:~9,2% -- mili-seconds
%date:~4,2%%date:~7,2%%date:~10,4% : MMDDYYYY
%date:~7,2%%date:~4,2%%date:~10,4% : DDMMYYYY
%date:~10,4%%date:~4,2%%date:~7,2% : YYYYMMDD
