在Windows (Windows XP)批处理脚本中，我需要格式化当前日期和时间，以便以后在文件名等中使用。
这类似于堆栈溢出问题如何在批处理文件中添加日期，但也包含时间。
到目前为止，我有这个:
echo %DATE%
echo %TIME%
set datetimef=%date:~-4%_%date:~3,2%_%date:~0,2%__%time:~0,2%_%time:~3,2%_%time:~6,2%
echo %datetimef%
这使:
28/07/2009
8:35:31.01
2009_07_28__ 8_36_01
是否有一种方法可以允许%TIME%中的个位数小时，以便我可以得到以下结果?
2009_07_28__08_36_01
当前回答
我今天遇到了这个问题，并解决了它:
SET LOGTIME=%TIME: =0%
它用0代替空格，基本上是零垫小时。
经过一些快速搜索，我没有发现它是否需要命令扩展(仍然使用SETLOCAL DISABLEEXTENSIONS)。
其他回答
使用%，当时间值为7-9时，您将遇到十六进制操作错误。为了避免这种情况，请使用delayeexpand并使用!min:~1!
如果你有PowerShell，另一个方法是调用它:
for /F "usebackq delims=Z" %%i IN (`powershell Get-Date -format u`) do (set server-time=%%i)
如前所述，只有在您知道当前用户使用的格式(例如，MM/dd/yy或dd-MM-yyyy，仅举两个例子)时，解析日期和时间才有用。这是可以确定的，但是当您完成所有的强调和解析时，您仍然会遇到使用了意想不到的格式的情况，需要进行更多的调整。
您还可以使用一些外部程序，它们将以您喜欢的格式返回日期段，但这样做的缺点是需要将实用程序与脚本/批处理一起分发。
也有批处理技巧使用CMOS时钟在一个相当原始的方式，但这是太接近裸线对大多数人来说，也不总是首选的地方来检索日期/时间。
下面是避免上述问题的解决方案。是的，它引入了一些其他问题，但就我的目的而言，我发现这是在现代Windows系统的.bat文件中创建日期戳的最简单、最清晰、最可移植的解决方案。这只是一个示例，但我认为您将看到如何修改其他日期和/或时间格式等。
reg copy "HKCU\Control Panel\International" "HKCU\Control Panel\International-Temp" /f
reg add "HKCU\Control Panel\International" /v sShortDate /d "yyMMdd" /f
@REM reg query "HKCU\Control Panel\International" /v sShortDate
set LogDate=%date%
reg copy "HKCU\Control Panel\International-Temp" "HKCU\Control Panel\International" /f
一个很好的单行技巧是使用cmd /c echo ^%time^%来避免早期变量展开
cmd /c echo ^%time^% & dir /s somelongcommand & cmd /c echo ^%time^%
因此，%DATE%的问题在于它依赖于区域设置。所以之前的大部分答案对我来说都不适用。如果你对确切的格式不挑剔，只是想要一个时间戳来区分文件，你可以这样做:
set _date=%DATE%-%TIME%
set _date=%_date:/=-%
set _date=%_date: =-%
set _date=%_date::=-%
set _date=%_date:.=-%
echo %_date%
这应该适用于大多数地区。如果它没有添加另一行，则设置_date=%_date:<offending_char>=-%以删除有问题的字符。例如:一个与文件名不兼容的字符或文件名中不希望出现的字符。
请注意，这并不符合问题所规定的确切标准。
我是这样做的:
REM Generate FileName from date and time in format YYYYMMTTHHMM
Time /T > Time.dat
set /P ftime= < Time.dat
set FileName=LogFile%date:~6%%date:~3,2%%date:~0,2%%ftime:~0,2%%ftime:~3,2%.log
echo %FileName%
LogFile201310170928.log
