我希望我的批处理文件只运行提升。如果没有提升，为用户提供一个选项，以提升的方式重新启动批处理。
我正在编写一个批处理文件来设置一个系统变量，将两个文件复制到Program files位置，并启动一个驱动程序安装程序。如果Windows 7/Windows Vista用户(启用了UAC，即使他们是本地管理员)在没有右键单击并选择“以管理员身份运行”的情况下运行它，他们将得到“访问拒绝”，复制这两个文件并写入系统变量。
如果用户实际上是管理员，我想使用一个命令自动重新启动提升的批处理。否则，如果他们不是管理员，我想告诉他们，他们需要管理员权限来运行批处理文件。我使用xcopy复制文件和REG ADD写入系统变量。我正在使用这些命令来处理可能的Windows XP机器。我在这个主题上发现了类似的问题，但没有一个是关于重新启动批处理文件的。
当前回答
对于某些程序，将超级秘密的__COMPAT_LAYER环境变量设置为RunAsInvoker可以工作。看看这个:
set "__COMPAT_LAYER=RunAsInvoker"
start regedit.exe
尽管这样，将没有UAC提示用户将继续没有管理权限。
其他回答
当一个CMD脚本需要管理员权限，并且你知道它，添加这一行到脚本的最顶部(在@ECHO OFF之后):
NET FILE > NUL 2>&1 || POWERSHELL -ex Unrestricted -Command "Start-Process -Verb RunAs -FilePath '%ComSpec%' -ArgumentList '/c \"%~fnx0\" %*'" && EXIT /b
NET FILE检查现有的Administrator权限。如果没有，PowerShell将在提升的shell中启动当前脚本(带其参数)，并关闭非提升的脚本。
使用powershell。
如果cmd文件很长，我使用第一个需要提升，然后调用一个做实际工作。
如果脚本是一个简单的命令，那么所有内容都可以放在一个cmd文件中。不要忘记在脚本文件中包含路径。
模板:
@echo off
powershell -Command "Start-Process 'cmd' -Verb RunAs -ArgumentList '/c " comands or another script.cmd go here "'"
示例1:
@echo off
powershell -Command "Start-Process 'cmd' -Verb RunAs -ArgumentList '/c "powershell.exe -NoProfile -ExecutionPolicy Bypass -File C:\BIN\x.ps1"'"
示例2:
@echo off
powershell -Command "Start-Process 'cmd' -Verb RunAs -ArgumentList '/c "c:\bin\myScript.cmd"'"
虽然不直接适用于这个问题，但因为它需要为用户提供一些信息，当我想运行从任务调度程序提升的.bat文件时，谷歌将我带到了这里。
最简单的方法是为.bat文件创建一个快捷方式，因为对于快捷方式，您可以直接从高级属性中设置以管理员身份运行。
从任务调度程序运行快捷方式，运行提升的.bat文件。
我把这个粘贴在脚本的开头:
:: BatchGotAdmin
:-------------------------------------
REM --> Check for permissions
>nul 2>&1 "%SYSTEMROOT%\system32\icacls.exe" "%SYSTEMROOT%\system32\config\system"
REM --> If error flag set, we do not have admin.
if '%errorlevel%' NEQ '0' (
echo Requesting administrative privileges...
goto UACPrompt
) else ( goto gotAdmin )
:UACPrompt
echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
echo args = "" >> "%temp%\getadmin.vbs"
echo For Each strArg in WScript.Arguments >> "%temp%\getadmin.vbs"
echo args = args ^& strArg ^& " " >> "%temp%\getadmin.vbs"
echo Next >> "%temp%\getadmin.vbs"
echo UAC.ShellExecute "%~s0", args, "", "runas", 1 >> "%temp%\getadmin.vbs"
"%temp%\getadmin.vbs" %*
exit /B
:gotAdmin
if exist "%temp%\getadmin.vbs" ( del "%temp%\getadmin.vbs" )
pushd "%CD%"
CD /D "%~dp0"
:--------------------------------------
如果不是，我使用PowerShell重新启动提升的脚本。把这些句子放在你剧本的最上面。
net file 1>nul 2>nul && goto :run || powershell -ex unrestricted -Command "Start-Process -Verb RunAs -FilePath '%comspec%' -ArgumentList '/c %~fnx0 %*'"
goto :eof
:run
:: TODO: Put code here that needs elevation
我从@Matt的答案中复制了“net name”方法。他的回答有更好的文档记录，并有错误消息等。这个版本的优势在于PowerShell已经在Windows 7及以上版本上安装并可用。没有临时VBScript (*.vbs)文件，也不需要下载工具。
只要您的PowerShell执行权限没有被锁定，这个方法应该不需要任何配置或设置就可以工作。
