如何在Windows命令行中以合适的格式获取当前日期/时间，以便在文件/文件夹名称中使用?

更新:现在是2016年，我将使用PowerShell，除非有一个真正令人信服的向后兼容的原因，特别是因为使用日期的区域设置问题。参见@npocmaka的https://stackoverflow.com/a/19799236/8479

什么是Windows命令行语句(s)，我可以使用以我可以放入文件名的格式获取当前日期时间?

我想要一个.bat文件，它将一个目录压缩成一个归档文件，其中当前日期和时间作为名称的一部分，例如Code_2008-10-14_2257.zip。有什么简单的方法可以做到这一点，独立于机器的区域设置吗?

我真的不介意日期格式，理想情况下它是yyyy-mm-dd，但任何简单的都可以。

到目前为止，我已经得到了这个，在我的机器上给我Tue_10_14_2008_230050_91:

rem Get the datetime in a format that can go in a filename.
set _my_datetime=%date%_%time%
set _my_datetime=%_my_datetime: =_%
set _my_datetime=%_my_datetime::=%
set _my_datetime=%_my_datetime:/=_%
set _my_datetime=%_my_datetime:.=_%

rem Now use the timestamp by in a new ZIP file name.
"d:\Program Files\7-Zip\7z.exe" a -r Code_%_my_datetime%.zip Code

我可以接受这个，但它似乎有点笨重。理想情况下，它应该更简短，并具有前面提到的格式。

我用的是Windows Server 2003和Windows XP Professional。我不想安装额外的实用程序来实现这一点(尽管我知道有一些工具可以很好地格式化日期)。

当前回答

另一种方法(credit):

@For /F "tokens=2,3,4 delims=/ " %%A in ('Date /t') do @( 
    Set Month=%%A
    Set Day=%%B
    Set Year=%%C
)

@echo DAY = %Day%
@echo Month = %Month%
@echo Year = %Year%

请注意，我在这里的答案仍然依赖于日期和月份的顺序，由区域设置决定-不知道如何解决这个问题。

2008-10-14 22:36:49

其他回答

在Windows 7中，这段代码适用于我:

SET DATE=%date%
SET YEAR=%DATE:~0,4%
SET MONTH=%DATE:~5,2%
SET DAY=%DATE:~8,2%
ECHO %YEAR%
ECHO %MONTH%
ECHO %DAY%

SET DATE_FRM=%YEAR%-%MONTH%-%DAY% 
ECHO %DATE_FRM%

2016-08-16 10:44:40

这是我使用的:

::Date Variables - replace characters that are not legal as part of filesystem file names (to produce name like "backup_04.15.08.7z")
SET DT=%date%
SET DT=%DT:/=.%
SET DT=%DT:-=.%

如果你想进一步的想法自动备份到7-Zip档案，我有一个免费/开放的项目，你可以使用或审查的想法:http://wittman.org/ziparcy/

2008-10-14 22:29:00

"d:\Program Files\7-Zip\7z.exe" a -r code_%date:~10,4%-%date:~4,2%-%date:~7,2%.zip

2009-12-04 19:44:01

给定一个已知位置，供函数形式参考。ECHOTIMESTAMP调用显示了如何将时间戳转换为变量(本例中为DTS)。

@ECHO off

CALL :ECHOTIMESTAMP
GOTO END

:TIMESTAMP
SETLOCAL  EnableDelayedExpansion
    SET DATESTAMP=!DATE:~10,4!-!DATE:~4,2!-!DATE:~7,2!
    SET TIMESTAMP=!TIME:~0,2!-!TIME:~3,2!-!TIME:~6,2!
    SET DTS=!DATESTAMP: =0!-!TIMESTAMP: =0!
ENDLOCAL & SET "%~1=%DTS%"
GOTO :EOF

:ECHOTIMESTAMP
SETLOCAL
    CALL :TIMESTAMP DTS
    ECHO %DTS%
ENDLOCAL
GOTO :EOF

:END

EXIT /b 0

并保存到文件，timestamp.bat，下面是输出:

2016-08-11 20:07:16

这并不是真的更简短，但可能是一种更灵活的方式(来源):

FOR /F "TOKENS=1* DELIMS= " %%A IN ('DATE/T') DO SET CDATE=%%B
FOR /F "TOKENS=1,2 eol=/ DELIMS=/ " %%A IN ('DATE/T') DO SET mm=%%B
FOR /F "TOKENS=1,2 DELIMS=/ eol=/" %%A IN ('echo %CDATE%') DO SET dd=%%B
FOR /F "TOKENS=2,3 DELIMS=/ " %%A IN ('echo %CDATE%') DO SET yyyy=%%B
SET date=%mm%%dd%%yyyy%

2008-10-14 22:31:53

如何在Windows命令行中以合适的格式获取当前日期/时间，以便在文件/文件夹名称中使用?

推荐文章

最新文章

标签