如何使用sed替换文件中的第一次出现?

我想在任何现有的#include之前，用一个额外的include指令更新大量的c++源文件。对于这类任务，我通常使用带有sed的小型bash脚本来重写文件。

我如何得到sed替换一个文件中字符串的第一次出现，而不是替换每一次出现?

如果我用

sed s/#include/#include "newfile.h"\n#include/

它替换所有#includes。

我们也欢迎为达到同样目的而提出的其他建议。

当前回答

我需要一个在GNU和BSD上都可以工作的解决方案，而且我也知道第一行永远不会是我需要更新的一行:

sed -e "1,/pattern/s/pattern/replacement/"

尝试//特性不重复模式对我不起作用，因此需要重复它。

其他回答

#!/bin/sed -f
1,/^#include/ {
    /^#include/i\
#include "newfile.h"
}

该脚本的工作原理:对于第1行和第一个#include(在第1行之后)之间的行，如果该行以#include开头，则在指定的行前面加上。

但是，如果第一个#include在第1行，那么第1行和下一个#include都将有该行前置。如果您正在使用GNU sed，它有一个扩展，其中0，/^#include/(而不是1，)将做正确的事情。

sed -e 's/pattern/REPLACEMENT/1' <INPUTFILE

 # sed script to change "foo" to "bar" only on the first occurrence
 1{x;s/^/first/;x;}
 1,/foo/{x;/first/s///;x;s/foo/bar/;}
 #---end of script---

或者，如果你喜欢:编辑注:只适用于GNU sed。

sed '0,/foo/s//bar/' file

源

使用GNU sed的-z选项，您可以像处理一行文件一样处理整个文件。这样，s/…/…/将只替换整个文件中的第一个匹配项。记住:s/…/…/只替换每行中的第一个匹配项，但是使用-z选项sed将整个文件视为一行。

sed -z 's/#include/#include "newfile.h"\n#include'

在一般情况下，您必须重写sed表达式，因为模式空间现在包含整个文件，而不仅仅是一行。一些例子:

s /文本。*//可以重写为s/text[^\n]*//。[^\n]匹配除换行符以外的所有内容。[^\n]*将匹配文本后的所有符号，直到出现换行符。 S /^text//可以重写为S /(^|\n)text//。 S /text$//可以重写为S /text(\n|$)//。

sed '0,/pattern/s/pattern/replacement/' filename

这对我很管用。

例子

sed '0,/<Menu>/s/<Menu>/<Menu><Menu>Sub menu<\/Menu>/' try.txt > abc.txt

编者注:两者都只适用于GNU sed。

推荐文章